mercredi 15 février 2017

Avec la 3D, on n'en a jamais fini...

Le code d'exportation de fichier au format Wavefront .obj se trouve en fin de cet article. Avec ce code, il est possible d'obtenir un rendu immédiatement avec Bryce ou Vue d'esprit par exemple.

Il est également possible d'afficher un objet en 3D dans un programme édité en freepascal avec Lazarus, en utilisant la méthode 'loadfromfile' de la scène 3D du composant TBGRAbitmap.

Pendant ce temps que j'ai composé le code d'exportation, j'ai fait des essais avec Bryce et Wings3D pour savoir si le résultat correspondait à mes attentes.

J'ai découvert qu'on pouvait faire des opérations de CSG
( Constructive Solid Geometry ) 
avec des objets de type obj
dans Bryce 7


Comme vous pourrez éventuellement le lire dans le code ci-après, le fichier obj est accompagné d'un second fichier, celui des matériaux (.mtl)
Voici un lien utile--> Wavefront .mtl file format

Voici un lien utile--> Wavefront .obj file format

Voici mon code minimum: 

PROCEDURE save_SOR3D( Filename1:String;PointsPerSection,SectionsPerSor:integer);
 VAR I,J,V1,V2,V3,V4:Integer; Ligne,TempString:string; format:TformatSettings;
 scrypt1:Tstrings;
 BEGIN

   // SOR veut dire 'Surface Of  Revolution'


//   Les variables V1,V2,V3,V4 sont déclarées dans un souci de clarté car une seule variable suffit...

   //TempString va nous donner le nom du fichier sans son extension '.obj'
     TempString:=extractfilename(Filename1);
     TempString:=Copy(tempstring,1, length(tempstring)-4);
   // On pourra y rajouter l'extension voulue par la suite (.obj, .mtl )
   // On va créer deux scrypts, un pour l'objet, l'autre pour le matériau

   // on sauvegardera les deux fichiers à la suite à la fin


   // On commence par l'objet

     scrypt1:=tstringlist.create;
     TRY

     scrypt1.clear;

     scrypt1.add('#Exported from SNGRAPH2D version 1.0 ( projet LAZARUS )');

     scrypt1.add('mtllib '+ TempString+'.mtl');

     scrypt1.add('o '+TempString);// le nom de l'objet = celui du fichier

     // cette ligne est facultative, inscrite en commentaire
     scrypt1.add('#'+intToStr(PointsPerSection * SectionsPerSor )+' vertices,'+' '
     + intToStr(2+((PointsPerSection-1) * SectionsPerSor ))+' faces');

     // Ici, on écrit dans le scrypt toutes les coordonnées de tous les sommets
     // du solide, à la suite
     // puis lors de la description des faces, c'est l'ordre dans lequel ces
     // sommets  (intitulés 'v' pour vertices) auront été enregistrés qui va nous
     // servir ( 1,2,3,4,5,6.......,n)


     // les vecteurs 3D sont bien-sûr déjà enregistrés - dans un tableau
     // à double entrée (SOR3D1) dont la variable d'enregistrement
     // des coordonnées X,Y,Z est
     // déclarée éventuellement dans le type IBGRAVertex3D;
     // on peut aussi créer un type Vecteur3D=record x,y,z:single end;

     format.DecimalSeparator:='.'; //(le fichier obj ne prend pas la virgule)

     FOR J:=1 TO SectionsPerSor DO
     FOR I:=1 TO PointsPerSection DO
     scrypt1.add('v '+FORmatfloat('0.########',SOR3D1[J][I].X,format)+' '+
     Formatfloat('0.########',SOR3D1[J][I].Y,format)+' '+
     Formatfloat('0.########',SOR3D1[J][I].Z,format));



      // ici nous n'avons qu'un seul groupe à déclarer dans notre programme
      // le nom du groupe peut être celui du fichier + '_default'

      scrypt1.add('g '+TempString+'_default');
      // un seul matériau
      scrypt1.add('usemtl default');

      // 's1' veut dire smooth tandis que 's off' signifie que les arêtes sont 'hard'
      scrypt1.add('s off');







          IF not POLYGON1.checked THEN     // pour le cas d'un tore il n'y a, ni
          BEGIN
                                         // face du haut, ni face du bas

          // Polygones du haut et du bas

          ligne:='f ';
          FOR I:=1 to SectionsPerSor DO
          BEGIN
          J:=1+PointsPerSection *(I-1);
          Ligne:=Ligne+inttostr(J)+' ' ;
          END;

          scrypt1.add(ligne);

          ligne:='f ';
          FOR I:= SectionsPerSor Downto 1 DO
          BEGIN
          J:=PointsPerSection+PointsPerSection *(I-1);
          Ligne:=Ligne+inttostr(J)+' ' ;
          END;

          scrypt1.add(ligne);

          END;

        // polYgones à 4 côtés


          FOR I:=1 to SectionsPerSor-1 DO
          BEGIN

                  FOR J:=1 to  PointsPerSection-1 DO
                  BEGIN
                  ligne:='f ';

                  V1:=J+PointsPerSection *(I-1);

                   Ligne:=Ligne+inttostr(V1)+' ' ;
                  V2:= J+PointsPerSection *(I);

                   Ligne:=Ligne+inttostr(V2)+' ' ;

                  V3:= J+1+PointsPerSection *(I);

                   Ligne:=Ligne+inttostr(V3)+' ' ;

                  V4:=J+1+PointsPerSection *(I-1);

                   Ligne:=Ligne+inttostr(V4) ;

                   // Quand une ligne est complétée, on l'ajoute au scrypt1
                   scrypt1.add(ligne);


                  END;
          END;

                  FOR J:=1 to  PointsPerSection-1 DO
                  BEGIN
                  ligne:='f ';

                   V1:=J+PointsPerSection *(SectionsPerSor-1);
                   Ligne:=Ligne+inttostr(V1)+' ' ;

                   V2:= J;
                   Ligne:=Ligne+inttostr(V2)+' ' ;

                   V3:= J+1;
                    Ligne:=Ligne+inttostr(V3)+' ' ;

                   V4:=J+1+PointsPerSection *(SectionsPerSor-1) ;
                   Ligne:=Ligne+inttostr(V4);

                  scrypt1.add(ligne);


                  END;

      // Quand les scrypts sont complets, on les sauvegarde sur le disque dur
     // dans le répertoire en cours, qu'on a choisi dans la boîte de dialogue
     // avant que cette routine soit appelée

     scrypt1.savetofile(filename1);

      // Puis ici, on s'occupe du matériau

     // on repart sur un scrypt neuf
     scrypt1.clear;

     scrypt1.add('#Exported as .mtl by SNGRAPH2D version 1 ( projet Lazarus )');

     scrypt1.add('newmtl default');
     scrypt1.add('Ka 0.300000 0.300000 0.300000');
     scrypt1.add('Kd 0.500000 0.500000 0.00000');
     scrypt1.add('Ns 0.07000');
     scrypt1.add('d 1.00000');



     // Quand les scrypts sont complets, on les sauvegarde sur le disque dur
     // dans le répertoire en cours, contenu dans la chaîne de caratères 'filename1',
     // qu'on a choisi dans la boîte de dialogue
     // avant que cette routine soit appelée


     scrypt1.savetofile(Copy(Filename1,1, length(Filename1)-4)+'.mtl')


     finallY scrypt1.free; END;



 END;    









Aucun commentaire:

Enregistrer un commentaire